Clocktimes between 1:00:00 and 2:00:00

apologies for the Google translation I am using.
I can’t seem to solve the following problem.

I am using the code below in VS2022 to control my aquarium via the serial port and an Arduino Mega.
The code works fine, so everything is switched as programmed until it is 1:00:00 (24-hour code).
Between exactly 1:00:00 and 2:00:00, everything that has to do with the clock hours does not work as it should.
Lights, pumps that should be switched off come on. Night lights go off.
At exactly 2:00:00, everything is back to normal.
I don’t know what exactly is going wrong.

I have already used timeValue, timeNow and the like, always the same problem, I am at my wits’ end.
Fish get scared when all the lights suddenly come on and shoot back and forth through the aquarium.
Some have already jumped out of the water.
Can anyone help me solve this annoying situation?

Kind regards,
Stan

code:

Public Class VISBAK

    Dim InputData As String = ""
    Dim flasch As Boolean = True

    Public P_Lichtbalk_Linksachter_Aan_Uit As Boolean               'A
    Public P_Lichtbalk_Rechtsvoor_Aan_Uit As Boolean                'B
    Public P_Spot_Links_Aan_Uit As Boolean                          'C
    Public P_Lichtbalk_Rechtsachter_Aan_Uit As Boolean              'D
    Public P_Lichtbalk_Linksvoor_Aan_Uit As Boolean                 'E
    Public P_Klok_Kaamlaag_Aan_Uit As Boolean                       'F
    Public P_Klok_Nachtverlichting_Aan_Uit As Boolean               'G
    Public P_Klok_CO2_Reactor_Aan_Uit As Boolean                    'U
    Public P_Reserve_Klok_Aan_Uit As Boolean                        'W
    Public P_Proc_Verwarming_Aan_Uit As Boolean                     'L
    Public P_Verklikker_Bijvulwater_Aan_Uit As Boolean              'M
    Public P_Proc_Bijvullen_Aan_Uit As Boolean                      'Q
    Public P_Proc_CO2_Dosering_Aan_Uit As Boolean                   'R
    Public P_Klok_Ontluchting_CO2_Aan_Uit As Boolean                'V
    Public P_Klok_Plantenbemesting_Aan_Uit As Boolean               'Z


    Private tb_Klok_Spot_Links As Object


    Public Event DataReceived As IO.Ports.SerialDataReceivedEventHandler


    Private Sub Form1_Load(ByVal sender As System.Object,
                   ByVal e As System.EventArgs) Handles MyBase.Load

        SerialPort1.PortName = "COM4"

        SerialPort1.BaudRate = 9600
        SerialPort1.Parity = IO.Ports.Parity.None
        SerialPort1.DataBits = 8
        SerialPort1.StopBits = IO.Ports.StopBits.One
        SerialPort1.Handshake = IO.Ports.Handshake.None
        SerialPort1.RtsEnable = True

        If Not SerialPort1.IsOpen Then
            SerialPort1.Open()
        End If
        P_Lichtbalk_Linksachter_Aan_Uit = True
        P_Lichtbalk_Rechtsvoor_Aan_Uit = True
        P_Spot_Links_Aan_Uit = True
        P_Lichtbalk_Rechtsachter_Aan_Uit = True
        P_Lichtbalk_Linksvoor_Aan_Uit = True
        P_Klok_Kaamlaag_Aan_Uit = True
        P_Klok_Nachtverlichting_Aan_Uit = True
        P_Proc_Verwarming_Aan_Uit = True
        P_Verklikker_Bijvulwater_Aan_Uit = True
        P_Proc_Bijvullen_Aan_Uit = True
        P_Proc_CO2_Dosering_Aan_Uit = True
        P_Klok_CO2_Reactor_Aan_Uit = True
        P_Klok_Ontluchting_CO2_Aan_Uit = True
        P_Klok_Plantenbemesting_Aan_Uit = True
        P_Reserve_Klok_Aan_Uit = True

    End Sub

    Private Sub SerialPort1_DataReceived(ByVal sender As System.Object,
     ByVal e As System.IO.Ports.SerialDataReceivedEventArgs) _
      Handles SerialPort1.DataReceived
        Dim inputData = SerialPort1.ReadLine
        Invoke(New Action(Of String)(AddressOf DoUpdate), inputData)
    End Sub

    Private Sub DoUpdate(inputData As String)

        Dim values() As String = inputData.Split(",")
        TextBox3.Text = "450" 'values(0)                  'Geleidbaarheid
        tb_temperatuur.Text = "24.5" 'values(1)            'Temperatuur
        tb_pH.Text = "6.7" 'values(2)                     'Zuurgraad       
        TextBox4.Text = values(3)                  'Bijvullen

    End Sub

    Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick

        Actueletijd.Text = DateTime.Now.ToLongTimeString

        If P_Proc_Bijvullen_Aan_Uit = True Then
            If TextBox4.Text = "1" Then
                SerialPort1.Write("Q")
                Tb_Bijvullen.BackColor = Color.Aqua
                TextBox4.BackColor = Color.Aqua
                tb_OL5.BackColor = Color.Red
            Else
                'TextBox4.Text = "0"
                SerialPort1.Write("q")
                Tb_Bijvullen.BackColor = Color.LightGreen
                TextBox4.BackColor = Color.LightGreen
                tb_OL5.BackColor = Color.LightGreen
            End If
        End If

        If P_Proc_Verwarming_Aan_Uit = True Then
            If tb_temperatuur.Text <= "23.5" And tb_temperatuur.Text <= "24.0" Then

                SerialPort1.Write("L")
                Tb_Verwarming.BackColor = Color.Aqua
                tb_OL1.BackColor = Color.Red
            Else
                SerialPort1.Write("l")
                Tb_Verwarming.BackColor = Color.LightGreen
                tb_OL1.BackColor = Color.LightGreen
            End If
        End If

        If P_Verklikker_Bijvulwater_Aan_Uit = True Then
            If tb_temperatuur.Text >= "0" And tb_temperatuur.Text <= "40" Then
                SerialPort1.Write("M")
                Tb_Verklikker_Bijvulwater.BackColor = Color.Aqua
                tb_OL3.BackColor = Color.Red
            Else
                SerialPort1.Write("m")
                Tb_Verklikker_Bijvulwater.BackColor = Color.LightGreen
                tb_OL3.BackColor = Color.LightGreen
            End If
        End If

        If P_Proc_CO2_Dosering_Aan_Uit = True Then
            If tb_pH.Text >= "6.6" And tb_pH.Text >= "6.4" Then
                SerialPort1.Write("R")
                Tb_CO2_Dosering.BackColor = Color.Aqua
                tb_B1.BackColor = Color.Red
            Else
                SerialPort1.Write("r")
                Tb_CO2_Dosering.BackColor = Color.LightGreen
                tb_B1.BackColor = Color.LightGreen
            End If
        End If

        If P_Lichtbalk_Linksachter_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "15:30" And DateTime.Now.ToShortTimeString <= "21:00" Then
                SerialPort1.Write("A")
                Btn_Klok_A.BackColor = Color.Yellow
                Tb_Lichtbalk_Linksachter.BackColor = Color.Yellow
                tb_B3.BackColor = Color.Red
            Else
                SerialPort1.Write("a")
                Tb_Lichtbalk_Linksachter.BackColor = Color.LightBlue
                Btn_Klok_A.BackColor = Color.Yellow
                tb_B3.BackColor = Color.LightGreen
            End If
        End If

        If P_Lichtbalk_Rechtsvoor_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "13:30" And DateTime.Now.ToShortTimeString <= "23:00" Then
                SerialPort1.Write("B")
                Btn_Klok_B.BackColor = Color.Yellow
                Tb_Lichtbalk_Rechtsvoor.BackColor = Color.Yellow
                tb_B7.BackColor = Color.Red
            Else
                SerialPort1.Write("b")
                Tb_Lichtbalk_Rechtsvoor.BackColor = Color.LightBlue
                Btn_Klok_B.BackColor = Color.Yellow
                tb_B7.BackColor = Color.LightGreen
            End If
        End If

        If P_Spot_Links_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "00:00" And DateTime.Now.ToShortTimeString <= "23:59" Then
                SerialPort1.Write("C")
                Btn_Klok_C.BackColor = Color.Yellow
                Tb_Spot_Links.BackColor = Color.Yellow
                tb_B4.BackColor = Color.Red
            Else
                SerialPort1.Write("c")
                Tb_Spot_Links.BackColor = Color.LightBlue
                Btn_Klok_C.BackColor = Color.Yellow
                tb_B4.BackColor = Color.LightGreen
            End If
        End If

        If P_Lichtbalk_Rechtsachter_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "15:45" And DateTime.Now.ToShortTimeString <= "21:30" Then
                SerialPort1.Write("D")
                Btn_Klok_D.BackColor = Color.Yellow
                Tb_Lichtbalk_Rechtsachter.BackColor = Color.Yellow
                tb_B8.BackColor = Color.Red
            Else
                SerialPort1.Write("d")
                Tb_Lichtbalk_Rechtsachter.BackColor = Color.LightBlue
                Btn_Klok_D.BackColor = Color.Yellow
                tb_B8.BackColor = Color.LightGreen
            End If
        End If

        If P_Lichtbalk_Linksvoor_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "13:00" And DateTime.Now.ToShortTimeString <= "22:30" Then
                SerialPort1.Write("E")
                Btn_Klok_E.BackColor = Color.Yellow
                Tb_Lichtbalk_Linksvoor.BackColor = Color.Yellow
                tb_B5.BackColor = Color.Red
            Else
                SerialPort1.Write("e")
                Tb_Lichtbalk_Linksvoor.BackColor = Color.LightBlue
                Btn_Klok_E.BackColor = Color.Yellow
                tb_B5.BackColor = Color.LightGreen
            End If
        End If

        If P_Klok_Kaamlaag_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "12:30" And DateTime.Now.ToShortTimeString <= "20:30" Then
                SerialPort1.Write("F")
                Btn_Klok_F.BackColor = Color.Yellow
                Tb_Kaamlaag.BackColor = Color.Yellow
                tb_B9.BackColor = Color.Red
            Else
                SerialPort1.Write("f")
                Tb_Kaamlaag.BackColor = Color.LightBlue
                Btn_Klok_F.BackColor = Color.Yellow
                tb_B9.BackColor = Color.LightGreen
            End If
        End If

        If P_Klok_Nachtverlichting_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "13:00" And DateTime.Now.ToShortTimeString <= "22:00" Then
                SerialPort1.Write("g")
                Btn_Klok_G.BackColor = Color.Yellow
                Tb_Nachtverlichting.BackColor = Color.LightBlue
                tb_B6.BackColor = Color.LightGreen
            Else
                SerialPort1.Write("G")
                Tb_Nachtverlichting.BackColor = Color.Yellow
                Btn_Klok_G.BackColor = Color.Yellow
                tb_B6.BackColor = Color.Red
            End If
        End If

        If P_Klok_CO2_Reactor_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "10:15" And DateTime.Now.ToShortTimeString <= "20:30" Then
                SerialPort1.Write("U")
                Btn_Klok_U.BackColor = Color.Yellow
                Tb_CO2_Reactorpomp.BackColor = Color.Yellow
                tb_OL6.BackColor = Color.Red
            Else
                SerialPort1.Write("u")
                Tb_CO2_Reactorpomp.BackColor = Color.LightBlue
                Btn_Klok_U.BackColor = Color.Yellow
                tb_OL6.BackColor = Color.LightGreen
            End If
        End If

        If P_Klok_Plantenbemesting_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "14:00" And DateTime.Now.ToShortTimeString <= "14:05" Then
                SerialPort1.Write("Z")
                Btn_Klok_Z.BackColor = Color.Yellow
                Tb_Plantenbemesting.BackColor = Color.Yellow
                tb_L2.BackColor = Color.Red
            Else
                SerialPort1.Write("z")
                Tb_Plantenbemesting.BackColor = Color.LightBlue
                Btn_Klok_Z.BackColor = Color.Yellow
                tb_L2.BackColor = Color.LightGreen
            End If
        End If

        If P_Klok_Ontluchting_CO2_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString >= "20:30:" And DateTime.Now.ToShortTimeString <= "20:31" Then
                SerialPort1.Write("V")
                Btn_Klok_V.BackColor = Color.Yellow
                Tb_Ontluchting_CO2.BackColor = Color.Yellow
                tb_O2.BackColor = Color.Red
            Else
                SerialPort1.Write("v")
                Tb_Ontluchting_CO2.BackColor = Color.LightBlue
                Btn_Klok_V.BackColor = Color.Yellow
                tb_O2.BackColor = Color.LightGreen
            End If
        End If


        If P_Reserve_Klok_Aan_Uit = True Then
            If DateTime.Now.ToShortTimeString <= "00:00" And DateTime.Now.ToShortTimeString >= "00:00" Then
                SerialPort1.Write("W")
                Btn_Klok_W.BackColor = Color.Yellow
                Tb_Reserve_Klok.BackColor = Color.Yellow
                tb_R5.BackColor = Color.Red
            Else
                SerialPort1.Write("w")
                Tb_Reserve_Klok.BackColor = Color.LightBlue
                Btn_Klok_W.BackColor = Color.Yellow
                tb_R5.BackColor = Color.LightGreen
            End If
        End If

    End Sub

Where is goes wrong for the times is using strings to compare times.

Where it could go horribly wrong (temperature, pH, conductivity) is using strings to compare numbers, if the code does something like switching on a heater based on that data.

Also, using UI controls to store data is not a good idea.

What you should do is:

Receive the serial data
Try to parse the values for conductivity, temperature, and pH into variables of type Double
Check that the values are reasonable, e.g., the pH is not 0 or 200, and so on.
If the values are reasonable, perform the appropriate actions, else alert the user.

You must do the parsing step to get the numbers as numbers. If the parsing didn’t work then there might have been electrical interference in the signal.

You must check that the values are reasonable in case a sensor failed.

Also, it is better to split the code up into smaller pieces. So you might have one Sub which deals with processing the temperature, another one for the pH, and so on, something like this:

Sub ProcessTemperature(temperatuur As Double)
    If P_Verklikker_Bijvulwater_Aan_Uit Then
        If temperatuur >= 0 AndAlso temperatuur <= 40 Then
            ' do something
        Else
            ' do something else
        End If
    End If
    ' More temperature-related code here.

End Sub

Sub ProcesspH(pH As Double)
    If pH > 6.6 AndAlso pH < 10 Then
        ' pH is too high, add CO2 to reduce the pH
        SerialPort1.Write("R")
        Tb_CO2_Dosering.BackColor = Color.Aqua
        tb_B1.BackColor = Color.Red
    End If

    If pH < 6.4 Then
        ' pH is too low, stop adding CO2
        ' ...
    End If

    ' Any other pH-related code here.

End Sub

Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick

    Dim temperatuur = 0.0

    If Double.TryParse(tb_temperatuur.Text, temperatuur) Then
        ProcessTemperature(temperatuur)
    Else
        ' Something has gone wrong. Maybe sound an alarm.
    End If

    Dim pH = 0.0

    If Double.TryParse(tb_pH.Text, pH) Then
        ProcesspH(pH)
    Else
        ' Something has gone wrong with the pH reading.
    End If

End Sub

Using a timer code to check for between 1:00:00 and 2:00:00

Private Shared ReadOnly oneAM As TimeSpan = TimeSpan.FromHours(1)
Private Shared ReadOnly twoAM As TimeSpan = TimeSpan.FromHours(2)
Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
    Dim TOD As TimeSpan = DateTime.Now.TimeOfDay
    If TOD >= oneAM AndAlso TOD < twoAM Then
        'between 1:00:00 and 1:59:59 inclusive
    ElseIf TOD >= twoAM Then
        ' 2:00:00 or grater
    End If
End Sub

Filed under: Kiến thức lập trình - @ 00:35

Thẻ: vb.netdatetime

Thiết kế website giá rẻ

Danh mục

Clocktimes between 1:00:00 and 2:00:00